Cum se calculează vârsta în Foi de calcul Google de la data nașterii

Foi de calcul Google poate fi folosit pentru mai mult decât pentru acumularea și organizarea datelor. De asemenea, îl puteți folosi pentru a determina ora curentă, pentru a crea diagrame și pentru a calcula vârsta folosind o dată de naștere. Acesta din urmă este descoperit prin utilizarea formulelor și funcțiilor integrate chiar în Foi de calcul Google.

Determinarea vârstei de la data nașterii în Foi de calcul Google

Când utilizați Foi de calcul Google, aveți două moduri predominante prin care să determinați vârsta de la data nașterii. Există DATEDIF , care este opțiunea mai flexibilă și YEARFRAC , alegerea mai simplă. Până la sfârșitul articolului, ar trebui să puteți determina nu numai vârsta unui singur individ, ci și cea a mai multor grupuri de persoane diferite simultan.

Voi începe lucrurile cu funcția DATEDIF.

Funcția DATEDIF

Înainte de a ne aprofunda în funcția în sine, va trebui să știm cum funcționează. Aceasta va necesita învățarea sintaxei pentru a fi utilizată cu funcția DATEDIF. Fiecare secțiune pe care ați introdus-o în Funcție se corelează cu o sarcină, vedeți aceste sarcini mai jos:

Sintaxă

=DATEDIF(data_începutului,data_terminării,unitatea)

captură de ecran pe Snapchat fără ca aceștia să știe

• data de început
  • Calculul va trebui să înceapă cu data nașterii.
• Data de încheiere
  • Aceasta va fi data la care se încheie calculul. Când se determină vârsta actuală, acest număr va fi probabil data de astăzi.

• unitate

• Opțiunile de ieșire care constau în: „Y”, „M”, „D”, „YM”, „YD” sau „MD”.

• Y – Numărul total de ani întregi, scurși între datele de început și de sfârșit introduse.
  • YM – „M” înseamnă luni de zile. Această ieșire arată numărul de luni după anii scurși complet pentru „Y”. Numărul nu va depăși 11.
  • YD – „D” înseamnă zile. Această ieșire arată numărul de zile după anii scurși complet pentru „Y”. Numărul nu va depăși 364.
• M – Numărul total de luni complet scurse între datele de început și de sfârșit introduse.
  • MD – Ca și în celelalte unități, „D” înseamnă zile. Această ieșire arată numărul de zile care urmează lunilor scurse complet pentru „M”. Nu poate depăși 30.
• D – Numărul total de zile complet scurse între datele de început și de sfârșit introduse.

Calculul

Acum că înțelegeți sintaxa care va fi utilizată, putem configura formula. După cum sa menționat anterior, funcția DATEDIF este opțiunea mai flexibilă atunci când se determină vârsta de la data nașterii. Motivul pentru aceasta este că puteți calcula toate detaliile vârstei într-un format de an, lună și zi.

Pentru început, vom avea nevoie de un exemplu de dată pe care să îl folosim în celulă. Am decis să pun data 14.07.1972 în celulă A1 . Vom face formula în celula din dreapta acesteia, B1 , dacă doriți să urmați pentru a înțelege.

Vom începe cu cea mai simplă versiune a formulei pentru a calcula vârsta. Dacă utilizați sintaxa de mai sus pentru a afla ce este ce, A1 este din punct de vedere tehnic data de început , astăzi va fi cel Data de încheiere , și vom determina vârsta în ani folosind 'Y' . De aceea, prima formulă utilizată va arăta astfel:

=datedif(A1,today(),"Y")

Sfat util: copiați și inserați formula direct în B2 și apăsați Enter pentru a primi rezultatul corespunzător.

Când este făcut corect, numărul, care indică vârsta calculată, va fi situat în B1 ca „46”.

Să facem aceeași formulă, doar că de data aceasta vom determina vârsta în luni de utilizare „M” în loc de „Y”.

=datedif(A1,today(),"M")

Totalul ar fi de 559 de luni. Are 559 de luni.

Cu toate acestea, acest număr este puțin absurd și cred că îl putem reduce la un nivel prin folosire 'ÎN' în loc doar de „M”.

=datedif(A1,today(),"YM")

Noul rezultat ar trebui să fie 7, care este un număr mult mai ușor de gestionat.

Doar pentru a fi amănunțit, să vedem cum vor arăta zilele folosind atât „YD”, cât și „MD”.

=datedif(A1,today(),"YD")

=datedif(A1,today(),"MD")

De data aceasta, rezultatele pentru „YD” sunt afișate în B1, iar rezultatul pentru „MD” este situat în celula B2.

Ai înțeles până acum?

În continuare, le vom combina pe toate într-un efort de a ne oferi un calcul mai detaliat. Formula poate deveni puțin agitată la tastare, așa că doar copiați și lipiți-o pe cea furnizată în celula B1.

Formula de utilizat este:

=datedif(A1,today(),"Y")&" Years "&datedif(A1,today(),"YM")&" months & "& datedif(A1,today(),"MD")&" days"

Ampersand este folosit pentru a uni fiecare formulă împreună ca o verigă de lanț. Acest lucru este necesar pentru a obține un calcul complet. Foaia dvs. Google ar trebui să conțină aceeași formulă ca:

Un calcul complet și detaliat ne-a oferit 46 de ani, 7 luni și 26 de zile. De asemenea, puteți utiliza aceeași formulă folosind funcția ArrayFormula. Aceasta înseamnă că puteți calcula mai mult decât o singură dată, dar și mai multe date.

Am ales câteva date la întâmplare și le-am conectat în celule suplimentare A2-A5 . Alege-ți propriile date și distrează-te puțin cu el. Pentru a utiliza funcția ArrayFormula, copiați și lipiți următoarele în celula B1:

=ArrayFormula(datedif(A1:A5,today(),"Y")&" Years "&datedif(A1:A5,today(),"YM")&" months & "& datedif(A1:A5,today(),"MD")&" days")

Acestea sunt rezultatele mele:

Acum, să presupunem că ați vrut să separați fiecare porțiune a datei în propria ei coloană mică, îngrijită, pentru a organiza bine. În Foi de calcul Google, adăugați start_date (data nașterii) într-o coloană și end_date în alta. Am ales celula B2 pentru start_date și C2 pentru end_date în exemplul meu. Întâlnirile mele se corelează cu nașterile și decesele recente ale celebrităților Burt Reynolds, Johnny Cash și Luke Perry.

După cum se arată, coloana A este numele persoanei, coloana B găzduiește data_de_început, iar C data_termină. Acum, voi adăuga încă patru coloane la dreapta. Unul pentru fiecare dintre „Y”, „YM”, „YD” și o combinație a tuturor celor trei. Acum trebuie doar să adăugați formulele corecte la fiecare rând pentru fiecare celebritate.

Burt Reynolds:

=DATEDIF(B2,C2,"Y") Schimbați „Y” în coloana corespunzătoare pe care încercați să o calculați.

Johnny Cash:

=DATEDIF(B3,C3,"Y") Schimbați „Y” în coloana corespunzătoare pe care încercați să o calculați.

Luke Perry:

=DATEDIF(B4,C4,"Y") Schimbați „Y” în coloana corespunzătoare pe care încercați să o calculați.

Pentru a obține formula JOINED, va trebui să utilizați o ArrayFormula așa cum am făcut mai devreme în articol. Puteți adăuga cuvinte precum Ani pentru a indica rezultatele anilor, plasându-l după formulă și între paranteze.

=ArrayFormula(datedif(B2,C2,"Y")&" Years "&datedif(B2,C2,"YM")&" months & "& datedif(B2,C2,"MD")&" days")

Formula de mai sus este pentru o celebritate. Cu toate acestea, dacă doriți să-i eliminați pe toți dintr-o singură lovitură, copiați și inserați următoarea formulă în celula G2:

=ArrayFormula(datedif(B2:B4,C2:C4,"Y")&" Years "&datedif(B2:B4,C2:C4,"YM")&" months & "& datedif(B2:B4,C2:C4,"MD")&" days")

Foaia dvs. Google ar trebui să arate cam așa:

Destul de îngrijit, nu? Este într-adevăr atât de simplu când utilizați funcția DATEDIF. Acum, putem trece la utilizarea funcției YEARFRAC.

Funcția YEARFRAC

Funcția YEARFRAC este una simplă pentru rezultate simple. Este direct la obiect, oferind un rezultat final fără toate rezultatele suplimentare adăugate pentru ani, luni și zile.

Iată o formulă de bază, aplicabilă doar unei singure celule:

=int(YEARFRAC(A1,today()))

cum se blochează un subredit în aplicație

Veți adăuga data nașterii în celula A1 și veți lipi formula în B1 pentru rezultat. Vom folosi data nașterii 04/11/1983 :

Rezultatul este vârsta de 35 de ani. Simplu, la fel ca atunci când utilizați funcția DATEDIF pentru o singură celulă. De aici putem trece la utilizarea YEARFRAC într-o ArrayFormula. Această formulă vă este mai utilă atunci când trebuie să calculați vârsta unor grupuri mari, cum ar fi studenți, membri ai facultății, membri ai echipei etc.

Va trebui să adăugăm o coloană cu diferite date de naștere. Am selectat coloana B, deoarece A va fi folosită pentru numele persoanelor. Coloana C va fi folosită pentru rezultatele finale.

Pentru a popula vârsta pe coloana alăturată, va trebui să folosim următoarea formulă:

=ArrayFormula(int(yearfrac(B2:B8,today(),1)))

Plasați formula de mai sus în celula C2 pentru a obține rezultatele.

Dacă preferați să continuați doar cu o coloană întreagă și să nu vă deranjați să aflați unde se termină, puteți adăuga o ușoară variație formulei. Tack pe IF și LEN spre începutul ArrayFormula astfel:

=ArrayFormula(if(len(B2:B),(int(yearfrac(B2:B,today(),1))),))

Aceasta va calcula toate rezultatele din acea coloană începând cu B2.